如何使用Zig编译器来构建C语言项目？

最近在学Zig，发现它是一门很不错的语言，有很多现代语言的特性。而且能够和C语言很好的融合。zig编译器也是一个很好的C语言编译器，能够很好的组织项目，无论是纯C语言项目，还是C语言和Zig语言的混合项目都能够很好地支持。由于Zig还在不断的发展，有些API会被抛弃掉。下面的项目是基于zig 0.14.0，实现了使用Zig编译器来构建C语言项目。

项目结构

├── build.zig
└── src
    ├── include
    │   └── print.h
    ├── lib
    │   ├── include
    │   │   └── max.h
    │   └── max.c
    ├── main.c
    └── print.c

代码

// main.c

#include "print.h"

int main(int argc, char *argv[]) {
    print_max(1, 2);
    return 0;
}

// print.h

#pragma once

void print_max(int a, int b);

// print.c

#include <stdio.h>

#include "max.h"

void print_max(int a, int b) {
    printf("max(%d, %d) = %d\n", a, b, max(a, b));
}

// max.h

#pragma once

int max(int a, int b);

// max.c

#include "max.h"

int max(int a, int b) { return a > b ? a : b; }

构建脚本

// build.zig

const std = @import("std");

const c_flags = [_][]const u8{"-std=c99"};

const c_lib_source_files = [_][]const u8{
    "src/lib/max.c",
};

const windows_c_lib_source_files = [_][]const u8{};
const linux_c_lib_source_files = [_][]const u8{};

const c_source_files = [_][]const u8{
    "src/main.c",
    "src/print.c",
};

pub fn build(b: *std.Build) void {
    const target = b.standardTargetOptions(.{});
    const optimize = b.standardOptimizeOption(.{});

    // 编译C库
    const lib = b.addStaticLibrary(.{
        .name = "max",
        .optimize = optimize,
        .target = target,
    });

    lib.linkLibC();
    lib.addIncludePath(
        .{
            .src_path = .{
                .owner = b,
                .sub_path = "./src/lib/include",
            },
        },
    );

    lib.addCSourceFiles(
        .{
            .files = &c_lib_source_files,
            .flags = &c_flags,
        },
    );

    // 演示宏传参
    lib.root_module.addCMacro("DISABLE_ZLIB", "TRUE");

    // 条件编译
    const t = lib.rootModuleTarget();
    switch (t.os.tag) {
        .windows => {
            lib.addCSourceFiles(
                .{
                    .files = &windows_c_lib_source_files,
                    .flags = &c_flags,
                },
            );
        },
        .linux => {
            lib.addCSourceFiles(
                .{
                    .files = &linux_c_lib_source_files,
                    .flags = &c_flags,
                },
            );
        },
        else => {},
    }

    b.installArtifact(lib);

    // 编译可执行程序
    const exe = b.addExecutable(.{
        .name = "main",
        .optimize = optimize,
        .target = target,
    });

    exe.addIncludePath(.{
        .src_path = .{
            .owner = b,
            .sub_path = "./src/include",
        },
    });

    exe.addIncludePath(.{
        .src_path = .{
            .owner = b,
            .sub_path = "./src/lib/include",
        },
    });

    exe.addCSourceFiles(
        .{
            .files = &c_source_files,
            .flags = &c_flags,
        },
    );

    exe.linkLibC();
    exe.linkLibrary(lib);
    b.installArtifact(exe);

    // 定义`zig build run`命令
    const run_cmd = b.addRunArtifact(exe);
    run_cmd.step.dependOn(b.getInstallStep());

    if (b.args) |args| {
        run_cmd.addArgs(args);
    }

    const run_step = b.step("run", "Run the app");
    run_step.dependOn(&run_cmd.step);
}

测试

• 编译：zig build

• 运行：zig build run